UVMの環境構築！(7) Agent

2022年9月28日 Simulation, UVM

UVMの環境構築第7回では、エージェントの定義（作成）方法について解説していきます。

なお、ソースコードはGitHubに公開しています。

シリーズ目次

UVMの環境構築！シリーズの目次は、第1回解説編の一番下をご覧ください。

UVMの環境構築！(1) 解説編

https://www.fpgaland.tech/making_uvm1/#uvm_seriese_list

今回から、UVMの検証環境構築について解説していきます。UVMは一見難しそうですが、一度環境を作ってみると、そんなに難しくありません。UVMは検証環境の再利用性向上を目的としていますので、FPGAの検証（シミュレーション）の生産性を向上させることがで...

エージェントの概要

エージェントはuvm_agentまたはそのサブクラスを継承して定義します。

通常、ドライバー、シーケンサー、コレクター、モニターはセットで使われます。エージェントは、これらをひとまとめにするためのコンポーネントです。したがって、DUTとやり取りをするひとかたまりのコンポーネントとなります（図1）。

１つのエンバイロンメントの中に、複数のエージェントを持つことも可能です。

エージェントの定義方法

エージェントでは、ドライバー、シーケンサー、コレクター、モニターのインスタンスを作成し、これらの接続を行います。

エージェントにはアクティブモードとパッシブモードがあります。

アクティブモード：スティミュラスを生成し、DUTのドライブする。その上で、DUTのインターフェース信号の監視を行う
パッシブモード：DUTのインターフェース信号の監視のみを行う

uvm_agentには、この切り替えを行うためのフィールドis_activeが定義されています。ユーザーはis_activeを使って、アクティブモードとパッシブモードを実装します。

virtual class uvm_agent extends uvm_component;
  uvm_active_passive_enum is_active = UVM_ACTIVE;
  ...
  ...
endclass

ほとんどの場合は、下記のmy_agent.svに示すような記述になります。

エージェントはコピペでOK。

my_agent

それでは、ソースコードを見ながら、エージェントの定義方法について説明します。

my_agent.sv

class my_agent extends uvm_agent;
 
    my_driver driver;
    my_sequencer sequencer;
    my_collector collector;
    my_monitor monitor;
 
    `uvm_component_utils_begin(my_agent)
        `uvm_field_enum(uvm_active_passive_enum, is_active, UVM_DEFAULT)    /* Defined in uvm_agent */
    `uvm_component_utils_end
 
    /* Constructor */
    function new(string name, uvm_component parent);
        super.new(name, parent);
    endfunction
 
    /* Build phase */
    function void build_phase(uvm_phase phase);
        super.build_phase(phase);
 
        collector = my_collector::type_id::create("collector", this);
        monitor = my_monitor::type_id::create("monitor", this);
 
        if (is_active == UVM_ACTIVE) begin
            driver = my_driver::type_id::create("driver", this);
            sequencer = my_sequencer::type_id::create("sequencer", this);
        end
    endfunction
 
    /* Connect phase */
    function void connect_phase(uvm_phase phase);
        super.connect_phase(phase);
 
        collector.analysis_port.connect(monitor.analysis_export);
 
        if (is_active == UVM_ACTIVE) begin
            driver.seq_item_port.connect(sequencer.seq_item_export);
        end
    endfunction
 
endclass

1行目：uvm_agentを継承して、my_agentを定義します。
3~6行目：ドライバー、シーケンサー、コレクター、モニターを定義します。
8~10行目：UVMマクロとフィールドマクロを書きます。is_activeはuvm_agentに定義されていますが、フィールドマクロは指定されていません。したがって、ユーザーはis_activeのフィールドマクロを指定する必要があります。
12~15行目：コンストラクタを定義します。
17~28行目：Build phaseを定義します。DUTの監視はアクティブモードの場合でもパッシブモードの場合でも行うため、まずはコレクターとモニターのインスタンスを作成します。次に、is_activeの値に応じて、アクティブモードの場合はドライバーとシーケンサーのインスタンスを作成します。
30~39行目：Connect phaseを定義します。まずは、コレクターのanalysis_portと、モニターのanalysis_exportを接続します。次に、アクティブモードの場合はドライバーのseq_item_portと、シーケンサーのseq_item_exportを接続します。